HTML Tidy als Filter in ASP.NET

Option Strict On
Option Explicit On 

Imports System.IO

Public Class TidyFilter : Inherits Stream

    Const TIDY_EXE As String = "tidy.exe"
    Const TIDY_CFG As String = "tidy.cfg"

    Private _sink As Stream
    Private _position As Long
    Private mstr As New MemoryStream

#Region "trivial"

    Public Sub New(ByVal sink As Stream)
        _sink = sink
    End Sub

    Public Overrides ReadOnly Property CanRead() As Boolean
        Get
            Return True
        End Get
    End Property

    Public Overrides ReadOnly Property CanSeek() As Boolean
        Get
            Return True
        End Get
    End Property

    Public Overrides ReadOnly Property CanWrite() As Boolean
        Get
            Return True
        End Get
    End Property

    Public Overrides ReadOnly Property Length() As Long
        Get
            Return 0
        End Get
    End Property

    Public Overrides Property Position() As Long
        Get
            Return _position
        End Get
        Set(ByVal Value As Long)
            _position = Value
        End Set
    End Property

    Public Overrides Function Seek(ByVal offset As Long, ByVal direction As System.IO.SeekOrigin) As Long
        Return _sink.Seek(offset, direction)
    End Function

    Public Overrides Sub SetLength(ByVal length As Long)
        _sink.SetLength(length)
    End Sub

    Public Overrides Sub Flush()
        _sink.Flush()
    End Sub

    Public Overrides Function Read(ByVal buffer() As Byte, ByVal offset As Integer, ByVal count As Integer) As Integer
        _sink.Read(buffer, offset, count)
    End Function

#End Region

    Public Overrides Sub Close()

        Dim path As String = System.Web.HttpContext.Current.Request.PhysicalApplicationPath

        Try

            'Prepare process.
            Dim psi As New System.Diagnostics.ProcessStartInfo
            psi.FileName = path & TIDY_EXE
            psi.Arguments = "-config " & path & TIDY_CFG
            psi.WorkingDirectory = path
            psi.CreateNoWindow = True
            psi.UseShellExecute = False
            psi.RedirectStandardInput = True
            psi.RedirectStandardOutput = True
            psi.RedirectStandardError = False

            'Create process.
            Dim p As New System.Diagnostics.Process
            p.StartInfo = psi

            If p.Start() Then

                'Feed Tidy.
                mstr.WriteTo(p.StandardInput.BaseStream)
                p.StandardInput.Close()

                'Write Tidy output into the original response stream.
                Const BUFFER_SIZE As Integer = 4096
                Dim buffer(BUFFER_SIZE) As Byte
                Dim count As Integer

                Do
                    count = p.StandardOutput.BaseStream.Read(buffer, 0, BUFFER_SIZE)
                    _sink.Write(buffer, 0, count)
                Loop Until count = 0
                p.StandardOutput.Close()

            Else
                Throw New Exception
            End If

        Catch ex As Exception

            'Something went wrong, output original source.
            mstr.WriteTo(_sink)

        Finally
            _sink.Close()
        End Try

    End Sub

    Public Overrides Sub Write(ByVal buffer() As Byte, ByVal offset As Integer, ByVal count As Integer)
        mstr.Write(buffer, offset, count)
    End Sub

End Class

Const TIDY_EXE As String = "cgi-bin\tidy.exe"
Const TIDY_CFG As String = "tidy.cfg"

Protected Overrides Sub OnInit(ByVal e As System.EventArgs)
    Response.Filter = new TidyFilter(Response.Filter)
End Sub